feat: added comment component

client/src/components/Comment.res

+type rec t = {
+  id: int,
+  level: int,
+  user: string,
+  time: int,
+  time_ago: string,
+  content: string,
+  comments: array<t>,
+}
+
+let pluralize = n => `${n->Js.Int.toString} ${n === 1 ? "reply" : "replies"}`
+
+@@warning("-39")
+@react.component
+let rec make = (~comment) => {
+  let (open_, setOpen) = React.useState(_ => true)
+
+  <li className="comment">
+    <div className="by">
+      <Link href={`/users/${comment.user}`}> {comment.user->React.string} </Link>
+      {" "->React.string}
+      {comment.time_ago->React.string}
+    </div>
+    <div className="text" dangerouslySetInnerHTML={{"__html": comment.content}} />
+    {comment.comments->Belt.Array.length > 0
+      ? <>
+          <div className={"toggle" ++ (open_ ? " open" : "")}>
+            <a onClick={_evt => setOpen(prevOpen => !prevOpen)}>
+              {(
+                open_ ? "[-]" : `[+] ${pluralize(comment.comments->Belt.Array.length)} collapsed`
+              )->React.string}
+            </a>
+          </div>
+          {open_
+            ? <ul className="comment-children">
+                {comment.comments
+                ->Belt.Array.map(comment =>
+                  React.createElement(
+                    make,
+                    makeProps(~comment, ~key={comment.id->Js.Int.toString}, ()),
+                  )
+                )
+                ->React.array}
+              </ul>
+            : React.null}
+        </>
+      : React.null}
+  </li>
+}
+@@warning("-39")

client/src/components/Comment.resi

+type rec t = {
+  id: int,
+  level: int,
+  user: string,
+  time: int,
+  time_ago: string,
+  content: string,
+  comments: array<t>,
+}
+
+@react.component
+let make: (~comment: t) => React.element